1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
<CsoundSynthesizer>
<CsOptions>
-odac
-m0
</CsOptions>
<CsInstruments>
/*
Debugger - Unfixed Bugs : BUG #5
http://git.1bpm.net/csd-unfixedbugs1/about/
By Richard Knight 2022
http://1bpm.net
q@1bpm.net
*/
sr = 44100
ksmps = 10
nchnls = 2
0dbfs = 1
seed 0
#define NOFILEIO ## ; file IO with readfi not supported on all platforms: disables bid_loadfile
;#define CPUSAVER ## ; improve CPU performance by degrading aesthetic performance
gkmastergain init 1 ; master gain
gkpump = 0 ; kick ducking control
gksection init -1
#include "wavetables.udo" ; general waveforms
#include "bussing.udo" ; global audio bussing
#include "bid.udo" ; Bug Infested Directive tools and parsing
#include "instruments.udo" ; sound generators
#include "txt_tools.udo" ; text tools
instr global_delay1
aL, aR bus_read "delay1"
aL *= abs(oscil(1, 1))
aR *= abs(oscil(1, 1))
aLdlr delayr 0.8
kdeltime = abs(oscil(0.02, 0.04)) + (gibid_beattime* 0.5)
aLdel deltapi kdeltime + 0.002
delayw aL + (aLdel * 0.7)
aRdlr delayr 0.8
aRdel deltapi kdeltime + 0.001
delayw aR + (aRdel * 0.7)
;aLdel *= 1-gkpump
;aRdel *= 1-gkpump
bus_mix("master", aLdel, aRdel)
endin
/*
Global send effects: reverb
*/
instr global_reverb
#ifndef CPUSAVER
aL, aR bus_read "reverb"
aL, aR freeverb aL, aR, 0.6, 0.3
bus_mix("master", aL, aR)
#endif
endin
/*
Master audio output
*/
instr global_master
igain = 1
aL, aR bus_read "master"
itime6 = tab_i(1, gibid_sectionlengths)*gibid_beattime
if (gksection == 6) then
khpf linseg 5, itime6*0.5, 10, itime6*0.3, 100, itime6*0.2, 500
klpf linseg 22050, itime6*0.5, 22050, itime6*0.3, 10000, itime6*0.2, 1000
aL butterhp butterlp(aL, klpf), khpf
aR butterhp butterlp(aR, klpf), khpf
endif
aL limit aL*0.5, -1, 1
aR limit aR*0.5, -1, 1
outs aL*gkmastergain*igain, aR*gkmastergain*igain
endin
/*
Parse BID file and run the sequencer
*/
instr parseandrun
tt_notify("Parsing events")
#include "bid_source.udo"
bid_loadtext(SBID)
tt_notify("Running sequencer")
event_i "i", "sequencer", 0, 3600
turnoff
endin
instr endfade
exitnow
endin
instr sequencer
isection = 1
event_i "i", "bid_setcurrentchord", 0, 1, isection, 0
event_i "i", "global_delay1", 0, p3
event_i "i", "global_reverb", 0, p3
event_i "i", "global_master", 0, p3
kmetro metro (gibid_tempo / 60) * 4
kpos init 0
kposabs init 0
ksection init isection
kposchord init 0
gksection = ksection
if (kmetro == 1) then
if (ksection > gibid_maxsection) then
event "i", "endfade", 0, gibid_beattime*8
turnoff
endif
bid_seq "kick", kpos, ksection
bid_seq "hat1", kpos, ksection
bid_seq "hat2", kpos, ksection
bid_seq "snare", kpos, ksection
bid_seq "mel1", kpos, ksection
bid_seq "stringchord", kpos, ksection
bid_seq "chord1", kpos, ksection
bid_seq "bass", kpos, ksection
bid_seq "clap", kpos, ksection
bid_seq "303", kpos, ksection
bid_seq "303b", kpos, ksection
kpos = (kpos < 31) ? kpos + 1 : 0
ksection16ths = bid_getsectionlength(ksection) * 4
if (kposabs+1 < ksection16ths) then
kposabs += 1
else
ksection += 1
kposchord = 0
kpos = 0
kposabs = 0
event "i", "bid_setcurrentchord", 0, 1, ksection, 1
endif
if (kposchord+1 < gkbid_chordlength*4) then
kposchord += 1
else
kposchord = 0
event "i", "bid_setcurrentchord", 0, 1, ksection, 1
endif
endif
endin
</CsInstruments>
<CsScore>
i"parseandrun" 0 1
</CsScore>
</CsoundSynthesizer>
|