1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
|
#ifndef UDO_BUSSING
#define UDO_BUSSING ##
/*
Bus handling
This file is part of the SONICS UDO collection by Richard Knight 2021, 2024
License: GPL-2.0-or-later
http://1bpm.net
*/
#ifdef BUS_MAINMIXER
gkmastervolume init 1
#end
/*
Get the stereo L and R names for a singular bus name
SnameL, SnameR bus_name Sbus
SnameL left bus identifier
SnameR right bus identifier
Sbus bus name
*/
opcode bus_name, SS, S
Sbus xin
xout sprintf("%sL", Sbus), sprintf("%sR", Sbus)
endop
/*
Read from a stereo bus, but do not clear it
aL, aR bus_tap Sbus
aL left channel
aR right channel
Sbus bus name
*/
opcode bus_tap, aa, S
Sbus xin
SbusL, SbusR bus_name Sbus
aL chnget SbusL
aR chnget SbusR
xout aL, aR
endop
/*
Read from a mono bus (or left channel of a stereo bus), but do not clear it
aout bus_tap Sbus
aout output audio
Sbus bus name
*/
opcode bus_tap, a, S
Sbus xin
SbusL, S_ bus_name Sbus
aout chnget SbusL
xout aout
endop
/*
Read from a stereo bus, and then clear the bus
aL, aR bus_read Sbus
aL left channel
aR right channel
Sbus bus name
*/
opcode bus_read, aa, S
Sbus xin
SbusL, SbusR bus_name Sbus
aL chnget SbusL
aR chnget SbusR
chnclear SbusL
chnclear SbusR
xout aL, aR
endop
/*
Read from a mono bus (or left channel of a stereo bus), and then clear the bus
aout bus_read Sbus
aout output audio
Sbus bus name
*/
opcode bus_read, a, S
Sbus xin
SbusL, S_ bus_name Sbus
aout chnget SbusL
chnclear SbusL
xout aout
endop
/*
Clear a stereo bus
bus_clear Sbus
Sbus bus name
*/
opcode bus_clear, 0, S
Sbus xin
SbusL, SbusR bus_name Sbus
chnclear SbusL
chnclear SbusR
endop
/*
Clear a mono bus (or left channel of a stereo bus)
bus_clear_mono Sbus
Sbus bus name
*/
opcode bus_clear_mono, 0, S
Sbus xin
SbusL, S_ bus_name Sbus
chnclear SbusL
endop
/*
Set to a stereo bus
bus_set Sbus, aL, aR
Sbus bus name
aL left channel
aR right channel
*/
opcode bus_set, 0, Saa
Sbus, aL, aR xin
SbusL, SbusR bus_name Sbus
chnset aL, SbusL
chnset aR, SbusR
endop
/*
Set to a mono bus (or left channel of a stereo bus)
bus_set Sbus, ain
Sbus bus name
ain input audio
*/
opcode bus_set, 0, Sa
Sbus, ain xin
SbusL, S_ bus_name Sbus
chnset ain, SbusL
endop
/*
Mix to a stereo bus
bus_mix Sbus, aL, aR
Sbus bus name
aL left channel
aR right channel
*/
opcode bus_mix, 0, Saa
Sbus, aL, aR xin
SbusL, SbusR bus_name Sbus
chnmix aL, SbusL
chnmix aR, SbusR
endop
/*
Mix to a mono bus (or left channel of a stereo bus)
bus_mix Sbus, ain
Sbus bus name
aL left channel
aR right channel
*/
opcode bus_mix, 0, Sa
Sbus, ain xin
SbusL, S_ bus_name Sbus
chnmix ain, SbusL
endop
/*
Mix to master bus
bus_masterout aL, aR
aL left channel
aR right channel
*/
opcode bus_masterout, 0, aa
aL, aR xin
chnmix aL, "mainL"
chnmix aR, "mainR"
endop
/*
Mix mono signal to master bus, equally across left and right
bus_masterout ain
ain input audio
*/
opcode bus_masterout, 0, a
ain xin
chnmix ain, "mainL"
chnmix ain, "mainR"
endop
/*
Record a bus to a wave file
bus_record Sbus, Spath
Sbus bus name
Spath path to file to record to
*/
opcode bus_record, 0, SS
Sbus, Spath xin
aL, aR bus_tap Sbus
fout Spath, 14, aL, aR
endop
/*
Record a mono bus (or left channel of a stereo bus) to a wave file
bus_record_mono Sbus, Spath
Sbus bus name
Spath path to file to record to
*/
opcode bus_record_mono, 0, SS
Sbus, Spath xin
asig bus_tap Sbus
fout Spath, 14, asig
endop
/*
Main output: anything mixed to the "main" bus goes to main outputs
*/
#ifdef BUS_MAINMIXER
instr _mainmixer
aL, aR bus_read "main"
aL = aL * gkmastervolume
aR = aR * gkmastervolume
outs aL, aR
endin
schedule("_mainmixer", 0, -1)
#end
#end
|