BUG4 finished

8 files changed, 1214 insertions, 0 deletions

diff --git a/BUG7/BUG7.csd b/BUG7/BUG7.csd
new file mode 100644
index 0000000..b1b478e
--- /dev/null
+++ b/BUG7/BUG7.csd
@@ -0,0 +1,192 @@
+<CsoundSynthesizer>
+<CsOptions>
+-odac
+-m0
+</CsOptions>
+<CsInstruments>
+/*
+	Debugger - Unfixed Bugs : BUG #7
+	
+	http://git.1bpm.net/csd-unfixedbugs1/about/
+
+	By Richard Knight 2021
+		http://1bpm.net
+		q@1bpm.net
+
+*/
+
+sr = 44100
+ksmps = 10
+nchnls = 2
+0dbfs = 1
+seed 0
+
+#define NOFILEIO ## 		; file IO with readfi not supported on all platforms: disables bid_loadfile
+
+gkmastergain init 1		; master gain
+gkpump = 0			; kick ducking control
+gksection init -1
+
+#include "wavetables.udo"	; general waveforms
+#include "bussing.udo"		; global audio bussing
+#include "bid.udo"		; Bug Infested Directive tools and parsing
+#include "instruments.udo"	; sound generators
+#include "txt_tools.udo"	; text tools
+
+
+
+instr global_delay1
+	itm = gibid_beattime
+	aL, aR bus_read "delay1"
+	aL multitap aL, itm/2, random(0.1, 0.5), itm/4, random(0.1, 0.5), itm*2, random(0.1, 0.5)
+	aR multitap aL, itm, random(0.1, 0.5), itm*3, random(0.1, 0.5), itm/8, random(0.1, 0.5)
+	bus_mix("master", aL*0.8, aR*0.8)
+endin
+
+/*
+	Master audio output
+*/
+instr global_master
+	igain = 1
+	aL, aR bus_read "master"
+
+	itime1 = tab_i(1, gibid_sectionlengths)*gibid_beattime
+
+	aclapL, aclapR bus_read "clap"
+	acofferL, acofferR bus_read "coffer"
+	akickL, akickR bus_read "kick"
+	ahat1L, ahat1R bus_read "hat1"
+	arimL, arimR bus_read "rim"
+	kclapamp init 0
+	kcofferamp init 0
+	if (gksection == 1) then
+		kclapamp linseg 0, itime1*0.6, 1, itime1*0.4, 1
+		kcofferamp line 0, itime1, 1
+		krevamp linseg 1, itime1*0.1, 0, itime1*0.9, 0
+		
+		arL, arR freeverb aL*2, aR*2, 0.9, 0.9
+		ir = 512
+		fL pvsanal arL, ir, ir/4, ir, 1
+		fR pvsanal arR, ir, ir/4, ir, 1
+		kshift = line(1000, itime1*0.1, 0)
+		kshifto = abs(oscil(100, 10))
+		f1L pvshift fL, kshift+kshifto, 300
+		f1R pvshift fR, kshift+kshifto, 300
+		arL pvsynth f1L
+		arR pvsynth f1R
+		aL = (krevamp*arL) + ((1-krevamp)*aL)
+		aR = (krevamp*arR) + ((1-krevamp)*aR)
+		
+
+	endif
+	aL += (aclapL * kclapamp) + (acofferL * kcofferamp) + (akickL * kclapamp) + (ahat1L * kcofferamp) + (arimL * kcofferamp)
+	aR += (aclapR * kclapamp) + (acofferR * kcofferamp) + (akickR * kclapamp) + (ahat1R * kcofferamp) + (arimR * kcofferamp)
+
+
+	aL limit aL*0.5, -1, 1
+	aR limit aR*0.5, -1, 1
+	outs aL*gkmastergain*igain, aR*gkmastergain*igain
+endin
+
+
+/*
+	Print notification of performance time since last notification
+		or if isection is -1, print completion notification
+*/
+gitimetrack times
+instr notify_change
+	isection = p4
+	itime times
+	if (isection == -1) then
+		tt_notify(sprintf"Complete, runtime: %s", tt_parsetime(itime)))
+		exitnow
+	else
+		isectiontime = itime - gitimetrack
+		tt_notify(sprintf("%s : section %d complete in %s", tt_parsetime(itime), isection, tt_parsetime(isectiontime)))
+		gitimetrack = itime
+	endif
+	turnoff
+endin
+
+
+/*
+	Parse BID file and run the sequencer
+*/
+instr parseandrun
+	tt_notify("Parsing events")
+
+	#include "bid_source.udo"
+	bid_loadtext(SBID)
+
+	tt_notify("Running sequencer")
+	event_i "i", "sequencer", 0, 3600
+	turnoff
+endin
+
+instr endfade
+	exitnow
+endin
+
+
+
+instr sequencer
+	isection = 1
+	event_i "i", "bid_setcurrentchord", 0, 1, isection, 0
+	event_i "i", "global_master", 0, p3
+	event_i "i", "global_delay1", 0, p3
+	kmetro metro (gibid_tempo / 60) * 4
+	kpos init 0
+	kposabs init 0
+	ksection init isection
+	kposchord init 0
+	gksection = ksection
+	if (kmetro == 1) then
+		if (ksection > gibid_maxsection) then
+			;event "i", "endfade", 0, gibid_beattime*8
+			event "i", "notify_change", p3, 1, -1
+			turnoff
+		endif
+
+		bid_seq "kick", kpos, ksection
+		bid_seq "koffer", kpos, ksection
+		bid_seq "clap", kpos, ksection
+		bid_seq "hat1", kpos, ksection
+		bid_seq "3031", kpos, ksection
+		bid_seq "3032", kpos, ksection
+		;bid_seq "hat2", kpos, ksection
+		bid_seq "rim", kpos, ksection
+		
+
+		kpos = (kpos < 31) ? kpos + 1 : 0
+		ksection16ths = bid_getsectionlength(ksection) * 4
+
+		if (kposabs+1 < ksection16ths) then
+			kposabs += 1
+		else
+			event "i", "notify_change", 0, 1, ksection
+			;event "i", "play_crash", 0, gibid_beattime*4
+			ksection += 1
+			kposchord = 0
+			kpos = 0
+			kposabs = 0
+			event "i", "bid_setcurrentchord", 0, 1, ksection, 1
+		endif
+		
+		
+		if (kposchord+1 < gkbid_chordlength*4) then
+			kposchord += 1
+		else
+			kposchord = 0
+			event "i", "bid_setcurrentchord", 0, 1, ksection, 1
+		endif
+		
+
+	endif
+
+endin
+
+</CsInstruments>
+<CsScore>
+i"parseandrun" 0 1
+</CsScore>
+</CsoundSynthesizer>
\ No newline at end of file
diff --git a/BUG7/basis.csd b/BUG7/basis.csd
new file mode 100644
index 0000000..ff5b2c5
--- /dev/null
+++ b/BUG7/basis.csd
@@ -0,0 +1,62 @@
+<CsoundSynthesizer>
+<CsOptions>
+-odac
+</CsOptions>
+<CsInstruments>
+sr = 44100
+kr = 4410
+nchnls = 2
+0dbfs = 1
+seed 0
+gifnSine = 1
+
+instr rim
+	icps = p4 ;1000
+	acps expon icps, 0.0025, icps * 0.5
+	acps = acps + icps
+	iamp = 0.1
+	a1a phasor acps, 0	
+	a1b phasor acps, random(0, 1)
+	afmenv expon 1.0, 0.02, 0.4
+	a1 = (a1a-a1b)*random(1, 10)*afmenv
+	acps = acps*(1.0+a1)
+	a0 oscil3 1.0, acps
+	aenv expon 1.0, 0.005, 0.5
+	a0 limit 4.0*a0*aenv, -1.0, 1.0
+	a0 butterhp a0, 230
+	aL, aR pan2 a0*iamp, random(0.3, 0.8)
+	outs aL, aR
+endin
+
+instr play_rim
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 3000
+	endif
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 1000
+	endif
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 2000
+	endif
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 500
+	endif
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 2500
+	endif
+	if (random:k(0, 1) > 0.3) then
+		event "i", "play_rim", 0, 0.4, 3500
+	endif
+endin
+
+
+</CsInstruments>
+<CsScore>
+i1 0 100
+f1 0 16384 10 1                                          ; Sine
+f2 0 16384 10 1 0.5 0.3 0.25 0.2 0.167 0.14 0.125 .111   ; Sawtooth
+f3 0 16384 10 1 0   0.3 0    0.2 0     0.14 0     .111   ; Square
+f4 0 16384 10 1 1   1   1    0.7 0.5   0.3  0.1          ; Pulse
+
+</CsScore>
+</CsoundSynthesizer>
\ No newline at end of file
diff --git a/BUG7/bid.udo b/BUG7/bid.udo
new file mode 100644
index 0000000..17e9be2
--- /dev/null
+++ b/BUG7/bid.udo
@@ -0,0 +1,425 @@
+#ifndef UDO_BID
+#define UDO_BID ##
+/*
+	Debugger - Unfixed Bugs : BUG #5
+
+	Bug Infested Directive file parser v1 and tools
+
+	Designed to create a reusable loop based score format in the Unfixed Bugs project and beyond.
+*/
+
+
+#define BID_VERSION #1.1#
+
+#include "txt_tools.udo"
+
+; globals
+gibid_tempo init -1		; beats per minute
+gibid_beattime init -1		; time of one beat in second
+gibid_maxsection init -1	; max number of sections
+gibid_chordfn init -1		; current chord ftable
+gkbid_chordlength init -1	; current chord length
+
+; BID internals
+gibid_sectionlengths ftgen 0, 0, -64, -7, 0	; section lengths
+gibid_sections[][] init 64, 64		; section pointers to data
+gibid_sectiondata[][] init 99, 6	; section data, ftables contained
+
+gibid_chordgroups[][] init 16, 12	; chord groups, pointers to sectionchords by section
+gibid_sectionchords[] init 16		; ftables of section chords
+
+gibid_currentchordnum = 0	; current chord number
+gibid_lastchordgroup = -1	; last chord group
+gibid_lastsection = -1		; last section
+
+gSbid_sequenced[] init 1	; internal tracking of sequenced elements
+gibid_sequenceinit init 1	; internal tracking of sequenced init
+gibid_swingtime init -1		; swing time calculated from percent
+
+/*
+	Get BID instrument index, creating new reference if specified.
+	Internal use only.
+	
+	index _bid_gettextindex Sname, [iaddifnotexists = -1]
+
+	index			BID instrument index
+
+	Sname			name to look up or create
+	iaddifnotexists		1=create , default=fatal if not exists
+*/
+opcode _bid_gettextindex, i, Sj
+	Sname, iaddifnotexists xin
+	ifinalindex = -1
+	index = 0
+	while (index < lenarray(gSbid_sequenced)) do
+		if (strcmp(gSbid_sequenced[index], Sname) == 0) then
+			ifinalindex = index
+			igoto complete
+		endif
+		index += 1
+	od
+
+	if (iaddifnotexists == 1) then
+		if (gibid_sequenceinit == 1) then
+			gibid_sequenceinit = 0
+			SequencedNew[] fillarray Sname
+			ifinalindex = 0
+		else
+			SequencedNew[] init lenarray(gSbid_sequenced) + 1
+			index = 0
+			while (index < lenarray(gSbid_sequenced)) do
+				SequencedNew[index] = gSbid_sequenced[index]
+				index += 1
+			od
+			SequencedNew[index] = Sname
+			ifinalindex = index
+		endif
+		gSbid_sequenced = SequencedNew
+		igoto complete
+	else
+		tt_notify_fatal(sprintf("Sequenced index for '%s' not found", Sname))
+	endif
+
+complete:
+	xout ifinalindex
+endop
+
+
+
+/*
+	Parse a row of comma-separated numerical values of either patterns or chords.
+	Internal use only.
+	
+	inum _bid_parserowitems Sline, ix1, ix2, imode
+
+	inum	number of elements found parsed 
+
+	Sline	input line
+	ix1	array dimension 1 index
+	ix2	array dimension 2 index
+	imode	0=count elements; 1=write patterns; 2=write chords
+*/
+opcode _bid_parserowitems, i, Siii
+	Sline, ix1, ix2, imode xin
+	inum = 0
+	while (strlen(Sline) > 0) do
+		icomma = strindex(Sline, ",")
+		Stemp = strsub(Sline, 0, icomma)
+		icomma = (icomma == -1) ? 0 : icomma
+		Sline = strsub(Sline, icomma + 1)
+		if (imode == 1) then
+			tabw_i strtod(Stemp), inum, gibid_sectiondata[ix1][ix2]
+		elseif (imode == 2) then
+			tabw_i strtod(Stemp), inum, gibid_chordgroups[ix1][ix2]
+		endif
+		inum += 1
+	od
+	xout inum
+endop
+
+
+/*
+	Read BID data for specified element and trigger accordingly.
+
+	bid_seq Splayer, kposition, ksection
+
+	Splayer		name of BID element
+	kposition	position in pattern provided by master sequencer
+	ksection	section in composition provided by master sequencer
+	
+*/
+opcode bid_seq, 0, Skk
+	Splayer, kpos, ksection xin
+	Sinstrument = sprintf("play_%s", Splayer)
+	instrindex = _bid_gettextindex(Splayer)
+	kdata = gibid_sections[ksection][instrindex]
+
+	if (kdata != -1) then ; null section
+		kon = tablekt:k(kpos, gibid_sectiondata[kdata][0])
+		
+		if (kon == 1) then
+			kchance = tablekt:k(kpos, gibid_sectiondata[kdata][3])
+			if (random:k(0, 1) < kchance) then
+				ktime = (kpos % 2 == 0) ? 0 : gibid_swingtime
+				kdur = tablekt:k(kpos, gibid_sectiondata[kdata][1]) * gibid_beattime
+				;kamp = tablekt:k(kpos, gisectiondata[kdata][2])
+				event "i", Sinstrument, ktime, kdur, kpos, kdata
+			endif		
+		endif
+	endif
+endop
+
+
+/*
+	Get a parameter for the specified pattern position.
+	ipos and idataindex are provided as p4 and p5 to instruments scheduled by bid_seq,
+	hence can typically used as bid_getparameter(p4, p5, iparameter)
+	
+	idata bid_getparameter ipos, idataindex, iparameter
+
+	idata		the resulting value
+
+	ipos		position in pattern
+	idataindex	section specific data index; pointer to ftable
+	iparameter	parameter index as in BID file; defaults include 0=on/off, 1=duration, 2=amp, 3=chance
+	
+*/
+opcode bid_getparameter, i, iii
+	ipos, idataindex, iparameter xin
+	xout tab_i(ipos, gibid_sectiondata[idataindex][iparameter])
+endop
+
+
+/*
+	Get a section length in beats
+
+	klength bid_getsectionlength ksection
+
+	klength		length in beats
+	
+	ksection	section to look up
+*/
+opcode bid_getsectionlength, k, k
+	ksection xin
+	xout tab:k(ksection, gibid_sectionlengths)
+endop
+
+/*
+	Parse a row of comma-separated values to either section patterns or chord storage.
+	Scans row, assigns ftable of appropriate length and then fills ftable.
+	Internal use only.
+
+	_bid_parserow Sline, ix1, ix2, imode
+
+	Sline		line to parse
+	ix1		array dimension 1 index of target storage
+	ix2		array dimension 2 index of target storage
+	imode		1=section patterns, 2=chords
+*/
+opcode _bid_parserow, 0, Siii
+	Sline, ix1, ix2, imode xin
+	isize = _bid_parserowitems(Sline, ix1, ix2, 0)
+	if (imode == 1) then
+		gibid_sectiondata[ix1][ix2] ftgen 0, 0, -isize, -7, 0
+	elseif (imode == 2) then
+		gibid_chordgroups[ix1][ix2] ftgen 0, 0, -isize, -7, 0
+	endif
+	isize = _bid_parserowitems(Sline, ix1, ix2, imode)
+endop
+
+
+
+/*
+	Parse a line from a BID string
+	Internal use only.
+
+	idataout[] _bid_parseline Sline, idatain[]
+
+	idataout[]	state data
+	
+	Sline		line to parse
+	idatain[]	state data
+	
+*/
+opcode _bid_parseline, i[], Si[]
+	Sline, idata[] xin
+	iparameter = idata[0]
+	isection = idata[1]
+	ichordnum = idata[2]
+	isectiondataindex = idata[3]
+	imode = idata[4]
+
+	if (strlen(Sline) > 0) then
+		Sfirstchar = strsub(Sline, 0, 1)
+
+		; comment
+		if (strcmp(Sfirstchar, ";") == 0) then 
+			; no action
+
+		; version check
+		elseif (strcmp(Sfirstchar, "v") == 0) then 
+			imode = 0
+			iversion = strtod(strsub(Sline, 2))
+			if (iversion != $BID_VERSION) then
+				tt_notify(sprintf("Incompatible BID file version: got %.2f , expected %.2f", iversion, $BID_VERSION))
+				exitnow
+			endif
+
+		; section header
+		elseif (strcmp(Sfirstchar, "s") == 0) then 
+			imode = 1
+			icomma = strindex(Sline, ",")
+			isectionnum = strtod(strsub(Sline, 2, icomma))
+			Sub = strsub(Sline, icomma+1)
+			icomma = strindex(Sub, ",")
+			isectionlength = strtod(strsub(Sub, 0, icomma))
+			ichordgroup = strtod(strsub(Sub, icomma+1))
+			gibid_sectionchords[isectionnum] = ichordgroup
+			tabw_i isectionlength, isectionnum, gibid_sectionlengths
+
+		; tempo
+		elseif (strcmp(Sfirstchar, "b") == 0) then 
+			imode = -1
+			icomma = strindex(Sline, ",")
+			gibid_tempo = strtod(strsub(Sline, 2, icomma))
+			gibid_beattime = 60 / gibid_tempo
+			iswingpercent = strtod(strsub(Sline, icomma+1))
+			gibid_swingtime = ((gibid_beattime/4)/100) * iswingpercent
+			
+		; chord group header
+		elseif (strcmp(Sfirstchar, "c") == 0) then 
+			imode = 3
+			ichordgroup = strtod(strsub(Sline, 2))
+			ichordnum = 0
+
+		; pattern header
+		elseif (strcmp(Sfirstchar, "i") == 0) then 
+			imode = 4
+			iparameter = 0
+			
+			icomma = strindex(Sline, ",")
+			instrindex = _bid_gettextindex(strsub(Sline, 2, icomma), 1)
+			Sub = strsub(Sline, icomma+1)
+			icomma2 = strindex(Sub, ",")
+			isection = strtod(strsub(Sub, 0, icomma2))
+			if (isection > gibid_maxsection) then
+				gibid_maxsection = isection
+			endif
+			if (icomma2 != -1) then ; repeat or null section
+				irepeatsection = strtod(strsub(Sub, icomma2+1))
+				if (irepeatsection == -1) then
+					inewsection = -1
+				else
+					inewsection = gibid_sections[irepeatsection][instrindex]
+				endif
+				gibid_sections[isection][instrindex] = inewsection
+			else
+				isectiondataindex += 1
+				gibid_sections[isection][instrindex] = isectiondataindex
+			endif
+
+		; chord row
+		elseif (imode == 3) then
+			_bid_parserow(Sline, ichordgroup, ichordnum, 2)
+			ichordnum += 1
+
+		; pattern row
+		elseif (imode == 4) then
+			_bid_parserow(Sline, isectiondataindex, iparameter, 1)
+			iparameter += 1
+		endif
+	endif
+	idata[0] = iparameter
+	idata[1] = isection
+	idata[2] = ichordnum
+	idata[3] = isectiondataindex
+	idata[4] = imode
+	xout idata
+endop
+
+
+/*
+	Parse a Bug Infested Directive Format string to global arrays, ftables and variables.
+	Handles patterns, tempo, chord groups and sections etc accordingly.
+
+	bid_loadtext Sfile, [imode = 0]
+
+	Stext	directive data as string to parse
+*/
+opcode bid_loadtext, 0, S
+	Stext xin
+	idata[] fillarray -1, -1, -1, -1, -1
+read:
+	index = strindex(Stext, "\n")
+	if (index != -1) then
+		Sline = strsub(Stext, 0, index)
+		Stext = strsub(Stext, index + 1)
+		idata[] _bid_parseline Sline, idata
+
+		igoto read
+	else
+		igoto complete
+	endif
+	
+complete:
+endop
+
+
+/*
+	Parse a Bug Infested Directive Format string to global arrays, ftables and variables.
+	Handles patterns, tempo, chord groups and sections etc accordingly.
+	Requires readfi support which is not available on all platforms. Platforms that do not support that
+	should set NOFILEIO.
+
+	bid_loadfile Sfile
+
+	Sfile	directive file to parse
+*/
+opcode bid_loadfile, 0, S
+	Sfile xin
+#ifdef NOFILEIO
+	tt_notify_fatal("Attempting to use parsefile when NOFILEIO is set")
+#else	
+	if (filevalid(Sfile) == 0) then
+		tt_notify(sprintf("Directive file cannot be found: '%s'", Sfile))
+		exitnow
+	endif
+	idata[] fillarray -1, -1, -1, -1, -1
+read:
+	Sline, ilinenum readfi Sfile
+	Sline = tt_stripnewline(Sline)
+
+	idata[] _bid_parseline Sline, idata
+
+	if (ilinenum != -1) igoto read
+#endif
+endop
+
+
+
+/*
+	Set the current chord given a section
+	p4	the section number
+	p5	0=start at beginning, 1=increment chord index
+*/
+instr bid_setcurrentchord
+	isection = p4
+	ichordincrement = p5
+	if (isection > gibid_maxsection) then
+		turnoff
+	endif
+
+	ichordgroup = gibid_sectionchords[isection]
+	if (ichordgroup != gibid_lastchordgroup || isection != gibid_lastsection) then
+		gibid_currentchordnum = 0
+		gibid_lastchordgroup = ichordgroup
+		gibid_lastsection = isection
+	elseif (ichordincrement == 1) then
+		if (gibid_currentchordnum + 1 < lenarray(gibid_chordgroups, 2) - 1) then
+			if (gibid_chordgroups[ichordgroup][gibid_currentchordnum + 1] == 0) then
+				gibid_currentchordnum = 0
+			else
+				gibid_currentchordnum += 1
+			endif
+		else
+			gibid_currentchordnum = 0
+		endif
+	else 
+		gibid_currentchordnum = 0
+	endif
+
+	ifn = gibid_chordgroups[ichordgroup][gibid_currentchordnum]
+	
+	if (ifn > 0) then
+		gkbid_chordlength = tab:k(0, ifn)
+		gibid_chordfn = ifn
+	endif
+
+	if (timeinstk() > 2) then
+		turnoff
+	endif
+endin
+
+
+#end
+
diff --git a/BUG7/bid_source.udo b/BUG7/bid_source.udo
new file mode 100644
index 0000000..bf034b4
--- /dev/null
+++ b/BUG7/bid_source.udo
@@ -0,0 +1,103 @@
+/*
+	Debugger - Unfixed Bugs : BUG #4
+
+	Bug Infested Directives source
+	Provided as a string due to readfi not being available on all platforms.
+	Used with bid_loadtext (whereas a separate file would be used with bid_loadfile and requires readfi support)
+*/
+
+SBID = {{
+; Bug Infested Directives : Debugger - Unfixed Bugs : BUG #7
+v 1.1
+
+; tempo, swing percent
+b 121, 27
+
+; chord groups
+c 1
+  4, 59, 63, 67, 69, 71, 72, 75, 77, 79, 82
+  4, 59, 63, 67, 69, 71, 72, 75, 77, 79, 82
+
+
+
+; sections: section number, length, chordgroup
+s 1, 256, 1
+s 2, 64, 1
+
+
+i glitchread, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3
+
+
+i 3031, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+
+i 3032, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+
+
+i clap, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3
+i clap, 2
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0
+ .1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+
+
+
+i rim, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+
+i hat1, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+ .3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1,.3,.1,.2,.1
+ .4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4,.4,.4, 1,.4
+ .9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9,.9
+
+
+i hat2, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 1, 1, 1, 1, 0, 0, 1, 1
+ .1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1,.1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1,.3,.3, 1, 1, 1, 1, 1, 1
+
+i kick, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  1, 0, 0, 1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 0, 0, 1, 1, 1, 1, 0, 0, 1, 0
+ .4,.4,.4,.9,.9,.4,.1,.1,.4,.4,.4,.4,.9,.9,.4,.1,.1,.4,.4,.4,.4,.9,.9,.4,.1,.1,.4,.4,.4,.4,.9,.9
+  1,.5,.8, 1, 1, 1,.5,.8, 1, 1, 1,.5,.8, 1, 1, 1,.5,.8, 1, 1, 1,.5,.8, 1, 1, 1,.5,.8, 1, 1, 1,.5
+  1, 1,.1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1,.1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1,.6,.2
+
+
+i koffer, 1
+; 1  -  -  -  2  -  -  -  3  -  -  -  4  -  -  -  5  -  -  -  6  -  -  -  7  -  -  -  8  -  -  -
+  0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1, 0, 1
+ .3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3,.3
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+  1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1
+
+}}
diff --git a/BUG7/bussing.udo b/BUG7/bussing.udo
new file mode 100644
index 0000000..78755ce
--- /dev/null
+++ b/BUG7/bussing.udo
@@ -0,0 +1,62 @@
+#ifndef UDO_BUSSING
+#define UDO_BUSSING ##
+
+
+/*
+	Get the stereo L and R names for a singular bus name
+	
+	SnameL, SnameR bus_name Sbus
+
+	SnameL		left bus identifier
+	SnameR		right bus identifier
+
+	Sbus		bus name
+*/
+opcode bus_name, SS, S
+	Sbus xin
+	xout sprintf("%sL", Sbus), sprintf("%sR", Sbus)
+endop
+
+
+/*
+	Mix to a stereo bus
+
+	bus_mix Sbus, aL, aR
+
+	Sbus	bus name
+	aL	left channel
+	aR	right channel
+*/
+opcode bus_mix, 0, Saa
+	Sbus, aL, aR xin
+	SbusL, SbusR bus_name Sbus
+	chnmix aL, SbusL
+	chnmix aR, SbusR
+endop
+
+
+
+/*
+	Read from a stereo bus, and then clear the bus
+	
+	aL, aR bus_read Sbus
+
+	aL	left channel
+	aR	right channel
+
+	Sbus	bus name
+*/
+opcode bus_read, aa, S
+	Sbus xin
+	SbusL, SbusR bus_name Sbus
+	aL chnget SbusL
+	aR chnget SbusR
+	chnclear SbusL
+	chnclear SbusR
+	xout aL, aR
+endop
+
+
+
+
+#end
diff --git a/BUG7/instruments.udo b/BUG7/instruments.udo
new file mode 100644
index 0000000..6c3bb31
--- /dev/null
+++ b/BUG7/instruments.udo
@@ -0,0 +1,272 @@
+#ifndef UDO_INSTRUMENTS
+#define UDO_INSTRUMENTS ##
+/*
+	Debugger - Unfixed Bugs : BUG #7
+
+	Sound generators
+	Names should correspond to those used in BID file, prepended with play_
+*/
+
+
+#include "wavetables.udo"
+#include "bussing.udo"
+#include "bid.udo"
+
+
+gi3031index = 1
+instr play_3031
+	iamp = bid_getparameter(p4, p5, 2)
+
+	
+	inote1 = table(gi3031index, gibid_chordfn, 0, 0, 1) 
+	if (gi3031index < 5) then
+		gi3031index += 1
+	else
+		gi3031index = 1
+	endif
+
+	ifilter = random(20, 40)
+
+	ifrq1 = 440 * exp(log(2) * (ifilter - 69) / 12)	; filter start freq.
+	kamp linseg 1, p3*0.8, 1, p3*0.2, 0
+	kcps init cpsmidinn(inote1)
+	kffrq port 0, 60/150, ifrq1		; filter frequency
+	a1 phasor kcps		; oscillator
+	a1 = 1 - 2 * a1
+
+	a1x butterbp a1, kffrq, kcps * 1.0			; filters
+	a1x =  a1x * (2 + kffrq / kcps)	; correct amplitude
+	a1 = a1x + a1 * 0.25 ; 0.5
+	a1 butterlp a1, kffrq
+
+	a1 = taninv(a1 * 2.5 * iamp)	; distortion ; 2.5
+
+	keqf limit kffrq * 4, 10, sr * 0.48	; EQ frequency
+	a1 pareq a1 * 0.6, keqf, 4.0, 1.0, 2
+	a1 pareq a1, 50, 1.3, 0.6
+	a1 pareq a1, 130, 0.6, 0.6
+	a1 = a1 * kamp * 0.8
+	;a1 *= line(0, p3, 1)
+	aL, aR pan2 a1, random(0.3, 0.7)
+	bus_mix("delay1", aL*0.3, aR*0.3)
+	bus_mix("master", aL, aR)
+endin
+
+
+gi3032index = 3
+instr play_3032
+	iamp = bid_getparameter(p4, p5, 2)
+
+	
+	inote1 = table(gi3032index, gibid_chordfn, 0, 0, 1) 
+	if (gi3032index < 9) then
+		gi3032index += 1
+	else
+		gi3032index = 3
+	endif
+
+	ifilter = random(20, 40)
+
+	ifrq1 = 440 * exp(log(2) * (ifilter - 69) / 12)	; filter start freq.
+	kamp linseg 1, p3*0.8, 1, p3*0.2, 0
+	kcps init cpsmidinn(inote1)
+	kffrq port 0, 60/150, ifrq1		; filter frequency
+	a1 phasor kcps		; oscillator
+	a1 = 1 - 2 * a1
+
+	a1x butterbp a1, kffrq, kcps * 1.0			; filters
+	a1x =  a1x * (2 + kffrq / kcps)	; correct amplitude
+	a1 = a1x + a1 * 0.25 ; 0.5
+	a1 butterlp a1, kffrq
+
+	a1 = taninv(a1 * 2.5 * iamp)	; distortion ; 2.5
+
+	keqf limit kffrq * 4, 10, sr * 0.48	; EQ frequency
+	a1 pareq a1 * 0.6, keqf, 4.0, 1.0, 2
+	a1 pareq a1, 50, 1.3, 0.6
+	a1 pareq a1, 130, 0.6, 0.6
+	a1 = a1 * kamp * 0.8
+	;a1 *= line(0, p3, 1)
+	aL, aR pan2 a1, random(0.3, 0.7)
+	bus_mix("delay1", aL*0.3, aR*0.3)
+	bus_mix("master", aL, aR)
+endin
+
+instr play_clap
+	iamp = bid_getparameter(p4, p5, 2) * random(0.4, 1) * 0.8
+	aL noise 1, 0.3
+	aR noise 1, 0.4
+	aL butterbp aL, random(1200, 1800), random(800, 1200)
+	aR butterbp aR, random(1200, 1800), random(800, 1200)
+	aL taninv aL*7
+	aR taninv aR*7
+	
+	kamp linseg 2, p3*0.1, 0, p3*0.1, 2, p3*0.1, 0, p3*0.1, 1.5, p3*0.1, 0, p3*0.1, 1, p3*0.4, 0
+	aL *= kamp * iamp
+	aR *= kamp * iamp
+	bus_mix("clap", aL, aR)
+	
+endin
+
+
+
+instr play_hat1
+	iamp = bid_getparameter(p4, p5, 2)
+	idel1 = random(0.005, 0.02)
+	idel2 = random(0.005, 0.02)
+	xtratim(max(idel1, idel2))
+
+	kfreq = 380 + oscil(50, 23);550 ;line 600, p3, 600
+	aenv expsega .1, .0005, 1.5, p3 - .0005, .01
+	asqr1 oscil 1, kfreq, gifnSquare, -1
+	asqr2 oscil 1, kfreq*1.4471, gifnSquare, -1
+	asqr3 oscil 1, kfreq*1.6170, gifnSaw, -1
+	asqr4 oscil 1, kfreq*1.9265, gifnSaw, -1
+	asqr5 oscil 1, kfreq*4.5028, gifnSine, -1
+	asqr6 oscil 1, kfreq*3.6637, gifnSine, -1
+	a808L sum asqr1, asqr2, asqr3
+	a808R sum asqr4, asqr5, asqr6
+	a808L butterhp a808L, 4270
+	a808R butterhp a808R, 4270
+	aoutL = a808L * aenv * iamp
+	aoutR = a808R * aenv * iamp
+	aL delay aoutL, idel1
+	aR delay aoutR, idel2
+	bus_mix("hat1", aL, aR)
+endin
+
+
+instr play_hat2
+	iamp = bid_getparameter(p4, p5, 2) * 0.7
+	kfreq line 880, p3, 400
+	aenv expsega .1, .0005, 1.5, p3 - .0005, .01
+	asqr1 oscil 1, kfreq, gifnSquare, -1
+	asqr2 oscil 1, kfreq*1.4471, gifnSquare, -1
+	asqr3 oscil 1, kfreq*1.6170, gifnSquare, -1
+	asqr4 oscil 1, kfreq*1.9265, gifnSquare, -1
+	asqr5 oscil 1, kfreq*2.5028, gifnSquare, -1
+	asqr6 oscil 1, kfreq*2.6637, gifnSquare, -1
+	a808L sum asqr4, asqr5, asqr6
+	a808R sum asqr1, asqr2, asqr3
+	a808L butterhp a808L, 3270
+	a808R butterhp a808R, 3270
+	aL = a808L * aenv * iamp
+	aR = a808R * aenv * iamp
+	bus_mix("master", aL, aR*0.7)
+endin
+
+
+instr rim
+	icps = p4 ;1000
+	iamp = p5
+	acps expon icps, 0.0025, icps * 0.5
+	acps = acps + icps
+	iamp = iamp * 0.3
+	a1a phasor acps, 0	
+	a1b phasor acps, random(0, 1)
+	afmenv expon 1.0, 0.02, 0.4
+	a1 = (a1a-a1b)*random(1, 10)*afmenv
+	acps = acps*(1.0+a1)
+	a0 oscil3 1.0, acps
+	aenv expon 1.0, 0.005, 0.5
+	a0 limit 4.0*a0*aenv, -1.0, 1.0
+	a0 butterhp a0, 230
+	aL, aR pan2 a0*iamp, random(0.3, 0.8)
+	bus_mix("rim", aL, aR)
+	bus_mix("delay1", butterlp(aL*0.6, 2000), butterlp(aR*0.6, 2000))
+endin
+
+
+instr blip1
+	iup = p4
+	iamp = p5
+	inote1 = table(p4+3, gibid_chordfn, 0, 0, 1) + iup
+	inote2 = table(p4+5, gibid_chordfn, 0, 0, 1) + iup
+	a1 oscil 0.7, cpsmidinn(inote1)
+	a2 oscil 0.7, cpsmidinn(inote2)
+	kamp linseg 1, p3*0.2, 0, p3*0.8, 0
+	a1 *= kamp
+	a2 *= kamp
+	a1 butterhp a1, 250
+	a2 butterhp a2, 250
+	a1 butterhp a1, 250
+	a2 butterhp a2, 250
+	aL1, aR1 pan2 a1, random(0, 1)
+	aL2, aR2 pan2 a2, random(0, 1)
+	bus_mix("master", aL1+aL2, aR1+aR2)
+	bus_mix("delay1", butterlp(aL1*0.5, 4000), butterlp(aR2*0.5, 4000))
+endin
+
+instr play_rim
+	iamp = bid_getparameter(p4, p5, 2)
+	if (random(0, 1) > 0.6) then
+		event_i "i", "rim", 0, 0.4, 3000, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "rim", 0, 0.4, 1000, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "rim", 0, 0.4, 2000, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "rim", 0, 0.4, 2500, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "rim", 0, 0.4, 3500, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "blip1", 0, random(0.01, 0.1), 48, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "blip1", 0, random(0.01, 0.1), 24, iamp
+	endif
+	if (random(0, 1) > 0.6) then
+		event_i "i", "blip1", 0, random(0.01, 0.1), 36, iamp
+	endif
+endin
+
+
+
+instr play_kick	; 808 style kick
+	iamp = bid_getparameter(p4, p5, 2)
+
+	idist = 0.5 ;= (i(gksection) == 1) ? 0.55 : 0.35
+	xtratim 0.1
+	krelease release
+	ktune init -1.5
+	kmul transeg 0.2, p3*0.5, -15, 0.01, p3*0.5, 0, 0
+	kbend transeg 0.5, 1.2, -4, 0, 1, 0, 0
+	asig gbuzz 0.5, 50*octave(ktune)*semitone(kbend), 20, 1, kmul, gifnCosine
+	aenv linseg 0, p3*0.8, 1, p3*0.2, 0
+	gkpump = k(aenv)
+	asig = asig*aenv
+	aenv linseg 0, 0.07, 1
+	acps expsega 400, 0.07, 0.001, 1, 0.001
+	amix = (asig*0.7)*1*iamp
+	gkpump = min(rms(amix) * 7, 1)
+	aout1 pareq amix, 100, 0.01, 0.7
+	aout1 distort aout1, idist, gifnSquare
+	aout1 pareq aout1, 50, 2, 0.4
+	aout1 pareq aout1, 190, 0.7, 0.6
+	aout1 butterlp aout1, 140
+	aout1 *= 2
+	bus_mix("kick", aout1, aout1)
+endin
+
+instr play_koffer
+	iamp = bid_getparameter(p4, p5, 2)
+	ifreq = cpsmidinn(tab_i(ftlen(gibid_chordfn) - 2, gibid_chordfn)+12)
+	aL buzz 2, ifreq, random(7, 12), gifnSquare
+	aL butterhp aL, 500
+	aR buzz 2, ifreq, random(7, 12), gifnSquare
+	aR butterhp aR, 500
+	kamp linseg 0, p3*0.2, 1, p3*0.1, 0, p3*0.7, 0
+	aL *= kamp 
+	aR *= kamp 
+	
+	bus_mix("koffer", aL, aR)
+endin
+
+
+
+#end
diff --git a/BUG7/txt_tools.udo b/BUG7/txt_tools.udo
new file mode 100644
index 0000000..eb0cc86
--- /dev/null
+++ b/BUG7/txt_tools.udo
@@ -0,0 +1,82 @@
+#ifndef UDO_TXTTOOLS
+#define UDO_TXTTOOLS ##
+/*
+	Debugger - Unfixed Bugs : BUG #3
+
+	Text tools
+*/
+
+
+/*
+	Print a notification prepended with a line of asterisks
+	
+	tt_notify Stext
+
+	Stext	text to print
+*/
+opcode tt_notify, 0, S
+	Stext xin
+	Snew = "\n"
+	iwidth = 60
+	index = 0
+	while (index < iwidth) do
+		Snew = strcat(Snew, "*");
+		index += 1
+	od
+	prints strcat(strcat(Snew, "\n"), strcat(Stext, "\n\n"))
+endop
+
+
+
+/*
+	Print a notification prepended with a line of asterisks and exit
+	
+	tt_notify Stext
+
+	Stext	text to print
+*/
+opcode tt_notify_fatal, 0, S
+	Stext xin
+	tt_notify(Stext)
+	exitnow
+endop
+
+
+/*
+	Return a number of seconds as HH:MM:SS format
+	
+	Stime tt_parsetime iseconds
+
+	iseconds	seconds to parse
+	
+	Stime		formatted time
+
+*/
+opcode tt_parsetime, S, i
+	input xin
+	ihours = floor(input / 3600)
+	iminutes = floor((input - (ihours * 3600)) / 60)
+	iseconds = input - (ihours * 3600) - (iminutes * 60)
+	xout sprintf("%02d:%02d:%05.2f", ihours, iminutes, iseconds)
+endop
+
+
+/*
+	Strip newline from end of line: built-in opcode has some problems
+
+	Soutput tt_stripnewline Sinput
+
+	Soutput		processed without newline at end if existent
+	
+	Sinput		line to process
+*/
+opcode tt_stripnewline, S, S
+	Sline xin
+	index = strindex(Sline, "\n")
+	if (index != -1) then
+		Sline = strsub(Sline, 0, index)
+	endif
+	xout Sline
+endop
+
+#end
diff --git a/BUG7/wavetables.udo b/BUG7/wavetables.udo
new file mode 100644
index 0000000..e81f075
--- /dev/null
+++ b/BUG7/wavetables.udo
@@ -0,0 +1,16 @@
+#ifndef UDO_WAVETABLES
+#define UDO_WAVETABLES ##
+/*
+	Debugger - Unfixed Bugs : BUG #3
+
+	General waveforms
+*/
+
+ipoints = 16384
+gifnCosine ftgen 0, 0, ipoints, 9, 1, 1, 90
+gifnSine ftgen 0, 0, ipoints, 10, 1
+gifnSquare ftgen 0, 0, ipoints, 10, 1, 0, 0.3, 0, 0.2, 0, 0.14, 0, .111
+gifnSaw ftgen 0, 0, ipoints, 10, 0, .2, 0, .4, 0, .6, 0, .8, 0, 1, 0, .8, 0, .6, 0, .4, 0, .2
+
+#end
+