From 9fbf91db06a6d4f4b5cd8bb45389a731bb86bf22 Mon Sep 17 00:00:00 2001
From: Richard <q@1bpm.net>
Date: Sun, 13 Apr 2025 18:48:02 +0100
Subject: initial

---
 site/app/clipart/clipart.csd | 63 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 site/app/clipart/clipart.csd

(limited to 'site/app/clipart/clipart.csd')

diff --git a/site/app/clipart/clipart.csd b/site/app/clipart/clipart.csd
new file mode 100644
index 0000000..570329a
--- /dev/null
+++ b/site/app/clipart/clipart.csd
@@ -0,0 +1,63 @@
+<CsoundSynthesizer>
+<CsOptions>
+-odac
+</CsOptions>
+<CsInstruments>
+ksmps = 64
+nchnls = 2
+0dbfs = 1
+seed 0
+
+#include "wavetables.udo"
+
+opcode oscbank, a, kkkkiiiiio
+	kfreq, kamp, kfreqstepmult, kampstepmult, ibands, iwidthamp, icentreamp, ihalfing, imaxrandrate, iband xin
+
+	aosc oscil kamp, min:k(kfreq, sr / 2)
+	aosc pdhalfy aosc, ihalfing
+	kwidth = abs:k(oscil:k(iwidthamp, random(0.1, imaxrandrate), gifnSine, random(0, 1)))
+	kcentre = abs:k(oscil:k(icentreamp, random(0.1, imaxrandrate), gifnSine, random(0, 1)))
+	aosc pdclip aosc, kwidth, kcentre
+	
+	if (iband < ibands) then
+		arecurse oscbank kfreq * kfreqstepmult, kamp * kampstepmult, kfreqstepmult, kampstepmult, ibands, iwidthamp, icentreamp, ihalfing, imaxrandrate, iband + 1
+		aosc += arecurse
+	endif
+	xout aosc
+endop
+
+
+instr playback
+	ixstart = p4
+	iystart = p5
+	ixend = p6
+	iyend = p7
+	icolour = p8
+	ivariation = p9
+	iwidth = p10
+	iheight = p11
+
+	istartfreq = (ixstart * 100) + 20
+	iendfreq = (ixend * 100) + 20
+	kfreq linseg istartfreq, p3, iendfreq
+
+	istartfstep = iystart + 1.3
+	iendfstep = iyend + 1.3
+	kfreqstepmult linseg istartfstep, p3, iendfstep
+
+	aamp linseg 0, p3 * 0.05, 1, p3 * 0.9, 1, p3 * 0.05, 0
+	ioscillators = max(1, int(100 / active:i("playback")))
+
+	aout oscbank kfreq, 0.1, kfreqstepmult, random(0.9, 0.99), ioscillators, iwidth, iheight, icolour, ivariation * 2
+	aout *= aamp * 0.5
+	kpan linseg iystart, p3, iyend
+	aL, aR pan2 aout, kpan
+
+	outs aL, aR
+endin
+
+</CsInstruments>
+<CsScore>
+f0 36000
+</CsScore>
+</CsoundSynthesizer>
\ No newline at end of file
-- 
cgit v1.2.3